Topic: Text Sytle

[Fabricio28]

Hi guys,
I'm trying to find if there are texts in my drawing that belong Standard Style, ROMAN and so on.
Is it possible find out a specific textstyle that exist in my drawing using lisp?

Let me explain better my task. In my drawing i created a linetype in standard style, but now i have to modify this linetype put 0 (zero) height.
I'd like to know if there are any text in my drawing that belong standard style before I change the height to 0 (zero).

Thank in advance

[alanjt]

?

Code: [Select]

(defun _usedTextStyles (blocks / style lst)
  (vlax-for block blocks
    (vlax-for x block
      (if
        (and (setq style (cond
                           ((vlax-property-available-p x 'StyleName) (vla-get-stylename x))
                           ((vlax-property-available-p x 'TextStyleName) (vla-get-textstylename x))
                         )
             )
             (not (member style lst))
        )
         (setq lst (cons style lst))
      )
    )
  )
  (vl-sort lst '<)
)
eg.

Code: [Select]

(_usedTextStyles (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))))

[CAB]

If you can delete the text style it is not in use.
Otherwise you may need to step through the database looking for that text style.
Another option is to ssget all TEXT & MTEXT and step through that selection set if blocks, fields & attributes are not to be considered.

[Fabricio28]

Thank you Alan,

Can I selected just the texts belong textstyle Standard my drawing?

Because your code is great, I know that exist standard. But I don't know which one is standard to delete or not.

Regards

[alanjt]

Thank you Alan,

Can I selected just the texts belong textstyle Standard my drawing?

Because your code is great, I know that exist standard. But I don't know which one is standard to delete or not.

Regards

Well, mine works in a sense that it checks the entire drawing database, so it will also check anything existing within blocks. Are you just interested in what can readily be selected in the drawing itself, not what's in the database?

[Fabricio28]

Yes Alan,
I'm not interested what's in the database.

I'd like select just the textstyle in my drawing.

[Lee Mac]

For non-nested Text/MText only:

Code - Auto/Visual Lisp: [Select]

1. (sssetfirst nil (ssget "_X" '((0 . "TEXT,MTEXT") (7 . "Standard"))))

[Fabricio28]

Thanks Mr. Lee

It's exactly I was looking for.

@ CAB and Alanjt

Thank very much, too.

Best Regards